dnl Process this file with autoconf to create configure.

dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(gnome-presence-applet, 0.3.1.90, chipx86@gnupdate.org)
AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2004-2005 Christian Hammond])

dnl ################################################################
dnl # Version information
dnl ################################################################
GNOME_PRESENCE_APPLET_MAJOR_VERSION=0
GNOME_PRESENCE_APPLET_MINOR_VERSION=3
GNOME_PRESENCE_APPLET_MICRO_VERSION=1
GNOME_PRESENCE_APPLET_DEVEL_VERSION=90

GNOME_PRESENCE_APPLET_VERSION=$GNOME_PRESENCE_APPLET_MAJOR_VERSION.$GNOME_PRESENCE_APPLET_MINOR_VERSION.$GNOME_PRESENCE_APPLET_MICRO_VERSION

if test "x$GNOME_PRESENCE_APPLET_DEVEL_VERSION" != "x0"; then
	GNOME_PRESENCE_APPLET_VERSION=$GNOME_PRESENCE_APPLET_VERSION.$GNOME_PRESENCE_APPLET_DEVEL_VERSION
fi

AC_DEFINE_UNQUOTED(GNOME_PRESENCE_APPLET_MAJOR_VERSION, $GNOME_PRESENCE_APPLET_MAJOR_VERSION,
	[gnome-presence-applet major version.])
AC_DEFINE_UNQUOTED(GNOME_PRESENCE_APPLET_MINOR_VERSION, $GNOME_PRESENCE_APPLET_MINOR_VERSION,
	[gnome-presence-applet minor version.])
AC_DEFINE_UNQUOTED(GNOME_PRESENCE_APPLET_MICRO_VERSION, $GNOME_PRESENCE_APPLET_MICRO_VERSION,
	[gnome-presence-applet micro version.])
AC_DEFINE_UNQUOTED(GNOME_PRESENCE_APPLET_VERSION, $GNOME_PRESENCE_APPLET_VERSION,
	[gnome-presence-applet version.])

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$GNOME_PRESENCE_APPLET_VERSION
PACKAGE=gnome-presence-applet

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)

dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_PROG_CC
AC_ARG_PROGRAM
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT
AC_HEADER_STDC

ALL_LINGUAS="fr pt_BR"
GETTEXT_PACKAGE=gnome-presence-applet
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])

AM_GLIB_GNU_GETTEXT

PKG_CHECK_MODULES(PACKAGE, \
	gtk+-2.0 >= 2.4.0 \
	libgnomeui-2.0 \
	libpanelapplet-2.0 \
	libglade-2.0 \
	libgalago-gtk >= 0.3.2)
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

AC_PATH_PROG(GCONFTOOL, gconftool-2, no)

if test "x$GCONFTOOL" = "xno"; then
	AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with Gconf])
fi

AM_GCONF_SOURCE_2

AC_PROG_INTLTOOL
GNOME_COMPILE_WARNINGS

dnl # Use wall if we have GCC
if test "x$GCC" = "xyes"; then
	CFLAGS="$CFLAGS -Wall"
fi

dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_CONFIG_FILES([
gnome-presence-applet.spec
Makefile
autopackage/Makefile
autopackage/default.apspec
data/Makefile
po/Makefile.in
src/Makefile
])

AC_OUTPUT

echo
echo $PACKAGE v$VERSION
echo

echo prefix............... : $prefix

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo