dnl Process this file with autoconf to create configure.

dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(galago-gtk-sharp, 0.5.0, chipx86@chipx86.com)
AC_PREREQ(2.50)
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2004-2006 Christian Hammond])


dnl ################################################################
dnl # Version information
dnl ################################################################
GALAGO_GTK_SHARP_MAJOR_VERSION=0
GALAGO_GTK_SHARP_MINOR_VERSION=5
GALAGO_GTK_SHARP_MICRO_VERSION=0
GALAGO_GTK_SHARP_DEVEL_VERSION=0

GALAGO_GTK_SHARP_VERSION=$GALAGO_GTK_SHARP_MAJOR_VERSION.$GALAGO_GTK_SHARP_MINOR_VERSION.$GALAGO_GTK_SHARP_MICRO_VERSION

if test "x$GALAGO_GTK_SHARP_DEVEL_VERSION" != "x0"; then
	GALAGO_GTK_SHARP_VERSION=$GALAGO_GTK_SHARP_VERSION.$GALAGO_GTK_SHARP_DEVEL_VERSION
fi

AC_DEFINE_UNQUOTED(GALAGO_GTK_SHARP_MAJOR_VERSION, $GALAGO_GTK_SHARP_MAJOR_VERSION,
	[galago-gtk-sharp major version.])
AC_DEFINE_UNQUOTED(GALAGO_GTK_SHARP_MINOR_VERSION, $GALAGO_GTK_SHARP_MINOR_VERSION,
	[galago-gtk-sharp minor version.])
AC_DEFINE_UNQUOTED(GALAGO_GTK_SHARP_MICRO_VERSION, $GALAGO_GTK_SHARP_MICRO_VERSION,
	[galago-gtk-sharp micro version.])
AC_DEFINE_UNQUOTED(GALAGO_GTK_SHARP_VERSION, "$GALAGO_GTK_SHARP_VERSION",
	[galago-gtk-sharp version.])


API_VERSION=1.0.0.0
AC_SUBST(API_VERSION)

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$GALAGO_GTK_SHARP_VERSION
PACKAGE=galago-gtk-sharp

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)

dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_PROG_CC
#AC_ARG_PROGRAM
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT

AM_PROG_LIBTOOL


dnl ################################################################
dnl # Look for Mono
dnl ################################################################
MONO_REQUIRED_VERSION=1.0
PKG_CHECK_MODULES(MONO, mono >= $MONO_REQUIRED_VERSION, has_mono=true, has_mono=false)

if test "x$has_mono" = "xtrue"; then
	AC_PATH_PROG(RUNTIME, mono, no)
	AC_PATH_PROG(CSC, mcs, no)

	GACUTIL_FLAGS='/package $(PACKAGE) /gacdir $(libdir) /root $(DESTDIR)$(libdir)'

	GENERATED_SOURCES=generated/*.cs

	if test `uname -s` = "Darwin"; then
		LIB_PREFIX=
		LIB_SUFFIX=.dylib
	else
		LIB_PREFIX=.so
		LIB_SUFFIX=
	fi

	AC_PATH_PROG(GAPI_FIXUP, gapi2-fixup, no)
	AC_PATH_PROG(GAPI_CODEGEN, gapi2-codegen, no)
else
	AC_PATH_PROG(CSC, csc.exe, no)

	GENERATED_SOURCES=generated\\\\*.cs

	GACUTIL_FLAGS=

	if test "x$CSC" = "xno"; then
		AC_MSG_ERROR([You need to install either Mono or .NET])
	else
		RUNTIME=
		LIB_PREFIX=
		LIB_SUFFIX=.dylib
	fi
fi

GTK_SHARP_PREFIX=`pkg-config --variable=prefix gtk-sharp-2.0`
AC_SUBST(GTK_SHARP_PREFIX)

PKG_CHECK_MODULES(GALAGO_SHARP, galago-sharp >= 0.5.0)
GALAGO_SHARP_PREFIX=`pkg-config --variable=prefix galago-sharp`
AC_SUBST(GALAGO_SHARP_PREFIX)

CS="C#"
if test "x$CSC" = "xno"; then
	AC_MSG_ERROR([No $CS compiler found])
fi

AC_PATH_PROG(GACUTIL, gacutil, no)
if test "x$GACUTIL" = "xno"; then
	AC_MSG_ERROR([No gacutil tool found])
fi

AC_SUBST(RUNTIME)
AC_SUBST(CSC)
AC_SUBST(LIB_PREFIX)
AC_SUBST(LIB_SUFFIX)
AC_SUBST(GACUTIL)
AC_SUBST(GACUTIL_FLAGS)
AC_SUBST(GENERATED_SOURCES)

GTK_SHARP_MIN_VERSION="1.0"
AC_SUBST(GTK_SHARP_MIN_VERSION)

PKG_CHECK_MODULES(GTK_SHARP, gtk-sharp-2.0 >= $GTK_SHARP_MIN_VERSION)
AC_SUBST(GTK_SHARP_CFLAGS)
AC_SUBST(GTK_SHARP_LIBS)

PKG_CHECK_MODULES(GALAGO_GTK, libgalago-gtk >= 0.5.0)
AC_SUBST(GALAGO_GTK_CFLAGS)
AC_SUBST(GALAGO_GTK_LIBS)


dnl ################################################################
dnl # Check if we want to use a tarball or svn for updates
dnl ################################################################
AC_ARG_WITH([galago-svn], AC_HELP_STRING([--with-galago-svn],
                                         [Build against libgalago-gtk SVN]),
[
	use_galago_svn=yes
],[
	if test "x$GALAGO_GTK_SHARP_DEVEL_VERSION" != "x0"; then
		use_galago_svn=yes;
	else
		use_galago_svn=no;
	fi
])

AM_CONDITIONAL(USE_GALAGO_SVN, test "x$use_galago_svn" = "xyes",
               [Define if using galago SVN.])


dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_CONFIG_FILES([
galago-gtk-sharp.pc
galago-gtk-sharp.spec
Makefile
galago-gtk/Makefile
galago-gtk/AssemblyInfo.cs
sources/Makefile
sources/galago-gtk-sharp-sources.xml
tests/Makefile
])

AC_OUTPUT

echo
echo $PACKAGE v$VERSION

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo